From 36d0b36dd4d21288c6210ece5c52adc83bb9531a Mon Sep 17 00:00:00 2001
From: sefidel <contact@sefidel.net>
Date: Thu, 20 Jan 2022 16:47:01 +0900
Subject: home/zellij: add module

---
 home/modules/programs/zellij/default.nix | 57 ++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 home/modules/programs/zellij/default.nix

(limited to 'home/modules')

diff --git a/home/modules/programs/zellij/default.nix b/home/modules/programs/zellij/default.nix
new file mode 100644
index 0000000..7edcb11
--- /dev/null
+++ b/home/modules/programs/zellij/default.nix
@@ -0,0 +1,57 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+let
+
+  cfg = config.programs.zellij;
+  yamlFormat = pkgs.formats.yaml { };
+
+in
+{
+  meta.maintainers = with lib.maintainers; [ boppyt ];
+
+  options.programs.zellij = {
+    enable = mkEnableOption "Zellij, A terminal workspace with batteries included.";
+
+    package = mkOption {
+      type = types.package;
+      default = pkgs.zellij;
+      defaultText = literalExpression "pkgs.zellij";
+      description = "The zellij package to install";
+    };
+
+    settings = mkOption {
+      type = with types;
+        let
+          prim = oneOf [ bool int str ];
+          primOrPrimAttrs = either prim (attrsOf prim);
+          entry = either prim (listOf primOrPrimAttrs);
+          entryOrAttrsOf = t: either entry (attrsOf t);
+          entries = entryOrAttrsOf (entryOrAttrsOf entry);
+        in attrsOf entries // { description = "zellij configuration"; };
+      default = { };
+      description = ''
+        Configuration written to
+        <filename>$XDG_CONFIG_HOME/zellij/config.yaml</filename>. See <link
+        xlink:href="https://zellij.dev/documentation/configuration.html"/>
+        for a list of available options.
+      '';
+      example = literalExample ''
+        {
+          default-mode = "normal";
+          simplified-ui = true;
+        }
+      '';
+    };
+  };
+
+  config = mkIf cfg.enable {
+
+    home.packages = [ cfg.package ];
+
+    xdg.configFile."zellij/config.yaml" = mkIf (cfg.settings != { }) {
+      source = yamlFormat.generate "zellij-config" cfg.settings;
+    };
+  };
+}
-- 
cgit 1.4.1