blob: 29531c50cd2f7cd7d3e6233f48b4df5368427862 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
{ config, lib, ... }:
with lib;
let
cfg = config.modules.expose;
in
{
options.modules.expose = {
enable = mkEnableOption "expose services to network";
routes = mkOption {
type = types.attrsOf types.str;
};
ssl = {
enable = mkEnableOption "SSL on all routes";
acmeHost = mkOption {
type = types.nullOr types.str;
default = null;
description = "ACMEHost for the certificate";
};
};
webmasterEmail = mkOption { type = types.str; description = "Email of the webmaster to be contacted for ACME events"; };
tailscaleIp = mkOption { type = types.str; description = "Tailscale IP for this node"; };
cloudflareUUID = mkOption { type = types.str; description = "UUID of the Cloudflare Tunnel"; };
secrets = {
acme-credentials = mkOption { type = types.path; description = "Path to the acme environment file"; };
cloudflare-credentials = mkOption { type = types.path; description = "Path to the cloudflare tunnel credentials"; };
};
};
config = mkIf cfg.enable {
assertions = [
{
assertion = cfg.ssl.enable -> cfg.ssl.acmeHost != null;
message = "ssl.acmeHost must be set when enabling SSL";
}
];
services.nginx.virtualHosts = mapAttrs (_: internal: {
locations."/".proxyPass = internal;
} // optionalAttrs (cfg.ssl.enable) {
forceSSL = true;
useACMEHost = cfg.ssl.acmeHost;
}) (filterAttrs
# Assume that reverse proxy is configured externally
(_: v: (!hasSuffix ":80" v) && (!hasSuffix ":443" v))
cfg.routes);
# Discard non-localhost mappings, and replace destination with tailscale IP
services.blocky.settings.customDNS.mapping = mapAttrs
(_: v: cfg.tailscaleIp)
(filterAttrs
(_: v: hasInfix "localhost" v)
cfg.routes);
services.cloudflared.tunnels."${cfg.cloudflareUUID}" = {
credentialsFile = cfg.secrets.cloudflare-credentials;
ingress = cfg.routes;
} // optionalAttrs (cfg.ssl.enable) {
# TODO: This seems to have no effect. Remove?
originRequest.originServerName = "*.${cfg.ssl.acmeHost}";
originRequest.caPool = config.security.acme.certs.${cfg.ssl.acmeHost}.directory;
};
};
}
|
